List Literals

3.3 List Literals

A list literal (the way you represent a list value within your program) is a list of comma-separated values enclosed in parentheses. These values form the elements of the list. For example:

(1, 2, 3)  # list of three values 1, 2, and 3
(1, 2, 3,)  # the same three values (the trailing comma is ignored)
("fred", 4.5)  # two values, "fred" and 4.5
( )  # empty list - zero elements
(1..100)  # list of 100 integers

That last one uses the .. range operator, which is seen here for the first time. That operator creates a list of values by counting from the left scalar up to the right scalar by ones. For example:

(1..5)  # same as (1, 2, 3, 4, 5)
(1.7..5.7)  # same thing - both values are truncated
(5..1)  # empty list - .. only counts "uphill"
(0, 2..6, 10, 12) # same as (0, 2, 3, 4, 5, 6, 10, 12)
($a..$b)  # range determined by current values of $a and $b
(0..$#rocks)  # the indices of the rocks array from the previous section

As you can see from those last two items, the elements of an array are not necessarily constants they can be expressions that will be newly evaluated each time the literal is used. For example:

($a, 17)  # two values: the current value of $a, and 17
($b+$c, $d+$e) # two values

Of course, a list may have any scalar values, like this typical list of strings:

("fred", "barney", "betty", "wilma", "dino")

3.3.1 The qw Shortcut

It turns out that lists of simple words (like the previous example) are frequently needed in Perl programs. The qw shortcut makes it easy to generate them without typing a lot of extra quote marks:

qw/ fred barney betty wilma dino / # same as above, but less typing

qw stands for "quoted words" or "quoted by whitespace," depending upon whom you ask. Either way, Perl treats it like a single-quoted string (so, you can't use \n or $fred inside a qw list as you would in a double-quoted string). The whitespace (characters like spaces, tabs, and newlines) will be discarded, and whatever is left becomes the list of items. Since whitespace is discarded, here's another (but unusual) way to write that same list:

qw/fred
  barney  betty
wilma dino/  # same as above, but pretty strange whitespace

Since qw is a form of quoting, though, you can't put comments inside a qw list.

The previous two examples have used forward slashes as the delimiter, but Perl actually lets you choose any punctuation character as the delimiter. Here are some of the common ones:

qw! fred barney betty wilma dino !
qw# fred barney betty wilma dino #  # like in a comment!
qw( fred barney betty wilma dino )
qw{ fred barney betty wilma dino }
qw[ fred barney betty wilma dino ]
qw< fred barney betty wilma dino >

As those last four show, sometimes the two delimiters can be different. If the opening delimiter is one of those "left" characters, the corresponding "right" character is the proper closing delimiter. Other delimiters use the same character for start and finish.

If you need to include the closing delimiter within the string as one of the characters, you probably picked the wrong delimeter. But even if you can't or don't want to change the delimiter, you can still include the character using the backslash:

qw! yahoo\! google excite lycos ! # include yahoo! as an element

As in single-quoted strings, two consecutive backslashes contribute one single backslash to the item.

Now, although the Perl motto is "There's More Than One Way To Do It," you may well wonder why anyone would need all of those different ways! Well, we'll see later that there are other kinds of quoting where Perl uses this same rule, and it can come in handy in many of those. But even here, it could be useful if you were to need a list of Unix filenames:

qw{
  /usr/dict/words
  /home/rootbeer/.ispell_english
}

That list would be quite inconvenient to read, write, and maintain if the slash were the only delimiter available.

 



Learning Perl
Learning Perl, 5th Edition
ISBN: 0596520107
EAN: 2147483647
Year: 2001
Pages: 205

flylib.com © 2008-2017.
If you may any questions please contact us: flylib@qtcs.net